Samenvatting

In dit artikel wordt stapsgewijs beschreven hoe u de functie INTERVAL kunt gebruiken in een matrixformule om de unieke elementen in een celbereik te tellen.


Terug naar begin

Unieke getalelementen tellen

Met de volgende formule wordt het aantal unieke waarden in het bereik A1:A10 geteld. Lege cellen en tekstvermeldingen worden niet meegeteld.


=SOM(ALS(INTERVAL(A1:A10;A1:A10)>0;1))
Opmerking De vorige en volgende formules zijn matrixformules. U kunt een matrixformule invoeren door op CTRL+SHIFT+ENTER te drukken. Als u een Macintosh-computer gebruikt, drukt u op COMMAND+RETURN.



De functie INTERVAL retourneert een getallenbereik. Met deze functie wordt voor de eerste keer dat een specifieke waarde voorkomt, een getal geretourneerd dat gelijk is aan het aantal keren dat deze waarde voorkomt. Voor elke volgende keer dat dezelfde waarde voorkomt, wordt met deze functie nul geretourneerd. Op deze manier wordt met deze functie het aantal unieke waarden geteld.


Terug naar begin

Unieke tekst- en getalelementen tellen

Omdat de functie INTERVAL alleen met getallen werkt, moet u een niveau toevoegen waarmee unieke teksvermeldingen (of vermeldingen met zowel getallen als tekst) worden herkend. Het niveau is in het volgende voorbeeld toegevoegd:


=SOM(ALS(INTERVAL(VERGELIJKEN(A1:A10;A1:A10;0);VERGELIJKEN(A1:A10;A1:A10;0))>0;1))
In het voorgaande voorbeeld wordt het aantal unieke tekst- en getalvermeldingen geteld in het bereik A1:A10. Het bereik A1:A10 bevat hierbij geen lege cellen.


Terug naar begin

Unieke elementen met lege cellen tellen

Als u unieke numerieke en tekstelementen wilt tellen in een bereik dat lege cellen bevat, voegt u een aanvullende test toe.


=SOM(ALS(INTERVAL(ALS(LENGTE(A1:A10)>0;VERGELIJKEN(A1:A10;A1:A10;0),""), ALS(LENGTE(A1:A10)>0;VERGELIJKEN(A1:A10;A1:A10;0);""))>0;1))
Terug naar begin

Som van de unieke getalelementen

Als u de unieke waarden voor een celbereik wilt optellen, vervangt u de laatste a1:a10 door de 1 uit de oorspronkelijke formule.


=SOM(ALS(INTERVAL(A1:A10;A1:A10)>0;A1:A10))
Terug naar begin