Samenvatting

In dit artikel wordt stapsgewijs beschreven hoe u met de functies voor datum en tijd in Microsoft Excel complexe datum- en tijdberekeningen kunt uitvoeren.

In Excel worden alle datums als gehele getallen en alle tijden als decimale breuken opgeslagen. Door dit systeem kunt u in Excel datums en tijden net als andere getallen optellen, aftrekken of vergelijken. Alle datums worden via dit systeem gemanipuleerd.

In dit systeem staat het seriële getal 1 voor 1-1-1900 12:00:00 AM. Tijden worden opgeslagen als decimale getallen tussen ,0 en ,99999, waarbij ,0 voor 00:00:00 staat en ,99999 voor 23:59:59 staat. De gehele getallen van de datum en de decimale breuken van de tijden kunnen worden gecombineerd. Het resultaat bestaat dan uit getallen met een decimaal gedeelte en een gedeelte met een geheel getal. Het getal 32331,06 staat bijvoorbeeld voor de datum en tijd 7-7-1988 1:26:24 AM.

In Excel beschikt u over veel ingebouwde datum- en tijdfuncties waarmee u complexe datum- en tijdberekeningen kunt uitvoeren.


Terug naar begin

De functie VANDAAG() en de functie NU()

De functie VANDAAG geeft het seriële getal van de datum van vandaag als resultaat op basis van uw systeemklok. Het resultaat bevat geen tijd. De functie NU geeft het seriële getal van de datum van vandaag als resultaat, plus de tijd.


Terug naar begin

Datums sorteren op basis van seriële getallen

In Excel worden datums gesorteerd op basis van het seriële getal van de datum in plaats van het weergegeven getal. Daarom kunt u onverwachte resultaten krijgen wanneer u datums sorteert in Excel.

Als u bijvoorbeeld een reeks datums met de notatie mmmm (zodat alleen de maand wordt weergegeven) sorteert, worden de maanden niet alfabetisch gesorteerd. In plaats daarvan worden de datums gesorteerd op basis van het onderliggende seriële getal voor de datum.


Terug naar begin

Datums vergelijken op basis van seriële getallen

Aangezien seriële getallen ook in vergelijkingen van datums en tijden worden gebruikt, kunnen de resultaten anders zijn dan verwacht (op basis van de weergegeven waarden).

Als u bijvoorbeeld met de functie NU een datum wilt vergelijken met de huidige datum, zoals in de formule
=ALS(NU()=DATUMWAARDE("10-1-1992");WAAR;ONWAAR)
, geeft de formule ONWAAR als resultaat, zelfs als de huidige datum 10-1-1992 is. WAAR wordt alleen als resultaat gegeven wanneer de datum 10-1-1992 12:00:00 AM is. Als u twee datums vergelijkt in een formule en de tijd niet in het resultaat is opgenomen, kunt u dit gedrag omzeilen door de functie VANDAAG te gebruiken:
=ALS(VANDAAG()=DATUMWAARDE("10-1-1992");WAAR;ONWAAR)
Terug naar begin

Werken met datumformules

Nagaan hoeveel dagen er zijn tussen vandaag en een datum in de toekomst

Gebruik de volgende formule om het aantal dagen tussen nu en een datum in de toekomst te bepalen:
="dd-mm-jj"-NU()
waarbij "dd-mm-jj" de datum in de toekomst is. Pas de opmaak Standaard toe op de cel met de formule.


Terug naar begin

Nagaan hoeveel dagen, maanden en jaren er zijn tussen twee datums

Als u het aantal dagen, maanden en jaren tussen twee datums wilt berekenen, waarbij u de begin- en einddatum in respectievelijk cel A1 en A2 invoert, voert u de volgende stappen uit:

1. Maak een nieuwe werkmap.
2. Typ de volgende gegevens in de werkmap:
   A1: 25-03-94 A2: 01-05-98
   
3. Typ de volgende formule in cel D1:
   =JAAR(A2)-JAAR(A1)-ALS(OF(MAAND(A2)<MAAND(A1);EN(MAAND(A2)=MAAND(A1); DAG(A2)<DAG(A1)));1;0)&" jaar, "&MAAND(A2)-MAAND(A1)+ALS(EN(MAAND(A2) <=MAAND(A1);DAG(A2)<DAG(A1));11;ALS(EN(MAAND(A2)<MAAND(A1);DAG(A2) >=DAG(A1));12;ALS(EN(MAAND(A2)>MAAND(A1);DAG(A2)<DAG(A1));-1)))&" maanden, "&A2-DATUM(JAAR(A2);MAAND(A2)-ALS(DAG(A2)<DAG(A1);1;0);DAG(A1))&" dagen"
   Opmerking Zorg ervoor dat er geen regeleinden in de formule staan wanneer u deze naar Excel kopieert en plakt, anders werkt de formule niet.

Als u de formule juist hebt getypt, wordt nu in cel D1 het volgende weergegeven:
4 jaar, 1 maanden, 6 dagen
Aanvullende opdeling van de formule voor dagen, maanden en jaren

Deze formule kan ook als volgt in aparte segmenten voor dagen, maanden en jaren worden opgedeeld:

Opmerking Zorg ervoor dat er geen regeleinden in deze formules staan wanneer u ze naar Excel kopieert en plakt, anders werken de formules niet.
Tijdsegment Formule ------------------------------------------------------------------------
Het resterende aantal =A2-DATUM(JAAR(A2);MAAND(A2)- dagen tussen twee datums, ALS(DAG(A2)<DAG(A1);1;0);DAG(A1))&"dagen" waarbij jaren en maanden worden genegeerd
Het resterende aantal =MAAND(A2)- MAAND(A1)+ALS(EN(MAAND(A2) maanden tussen twee datums, <=MAAND(A1); DAG(A2)<DAG(A1));11; waarbij jaren en dagen worden genegeerd ALS(EN(MAAND(A2)<MAAND(A1);DAG(A2)>= DAG(A1));12;ALS(EN(MAAND(A2)>MAAND(A1); DAG(A2)<DAG(A1));-1)))&" maanden"
Het aantal hele jaren =JAAR(A2)-JAAR(A1)-ALS(OF(MAAND(A2)< tussen twee datums MAAND(A1);EN(MAAND(A2)=MAAND(A1); DAG(A2)<DAG(A1)));1;0)&" jaren"
Opmerking In het eerdere voorbeeld zijn de &" dagen", &" maanden" en &" jaren" optioneel. Hier kunt u in de resultaten onderscheid maken tussen dagen, maanden en jaren.


Terug naar begin

Nagaan hoeveel weekdagen er zijn tussen twee datums

Als u het aantal weekdagen tussen twee datums wilt nagaan, waarbij u de begin- en einddatum in respectievelijk cel A1 en A2 invoert, voert u de volgende stappen uit:

1. Maak een nieuwe werkmap.
2. Typ de volgende gegevens in de werkmap:
   A1: 25-03-94 A2: 01-05-98
   
3. Typ de volgende formule in cel D1:
   =NETTO.WERKDAGEN(A1;A2)
   

1071 is het resultaat.

Opmerking Als het resultaat #NAAM is, klikt u op Invoegtoepassingen in het menu Extra. Schakel het selectievakje Analysis ToolPak in en klik op Ja als u wordt gevraagd of u dit wilt installeren.


Terug naar begin

Datums met stappen laten toenemen

Als u een datum wilt laten toenemen met een aantal jaren, maanden of dagen, gebruikt u de formule
=DATUM(JAAR(verwijzing)+waarde1;MAAND(verwijzing)+waarde2;DAG(verwijzing)+waarde3)
waarbij verwijzing de datumwaarde of celverwijzing is die de datum bevat en waarde1, waarde2 en waarde3 aangeven met welke hoeveelheid respectievelijk het jaar, de maand en de dag moeten toenemen.

Als u bijvoorbeeld een datum met een maand wilt laten toenemen, is de formule:
=DATUM(JAAR(DATUMWAARDE("20-6-96"));MAAND(DATUMWAARDE("20-6-96"))+1; DAG(DATUMWAARDE("20-6-96")))
Terug naar begin

Werken met tijdformules

Verstreken tijd berekenen

Wanneer u de inhoud van een cel aftrekt van een andere cel om de hoeveelheid tijd te bepalen die tussen deze twee tijdstippen is verstreken, is het resultaat een serieel getal dat de verstreken uren, minuten en seconden aanduidt. Als u het getal gemakkelijker leesbaar wilt maken, past u de tijdnotatie u:mm toe in de cel met het resultaat.

In het volgende voorbeeld bevatten cel C2 en D2 de formule =B2-A2 en heeft cel C2 de opmaak Standaard. In dit geval wordt in deze cel een decimaal getal (het seriële getal dat 12 uur en 45 minuten aanduidt: 0,53125) weergegeven.
A1: Begintijd B1: Eindtijd C1: Verschil D1: Verschil (Standaard) (u:mm) A2: 06:30:00 B2: 19:15:00 C2: 0,53125 D2: 12:45
Als middernacht tussen de begin- en eindtijd valt, moet u rekening houden met het tijdsverschil van 24 uur. Dit doet u door het getal 1 toe te voegen, waarmee een periode van 24 uur wordt aangeduid. U kunt bijvoorbeeld de volgende tabel opstellen, waarbij tijdsperioden kunnen doorlopen tot na middernacht.
A1: Begintijd B1: Eindtijd C1: Verschil D1: Verschil (Standaard) (u:mm) A2: 19:45:00 B2: 10:30:00 C2: 0,61458333 D2: 14:45
U maakt deze tabel door de volgende formule in cel C2 en D2 te typen:
=B2-A2+ALS(A2>B2;1)
Terug naar begin

Uren en minuten verzamelen die groter zijn dan 24 uur

Als u een tijdsperiode die groter is dan 24 uur op de juiste manier wilt weergeven, gebruikt u de ingebouwde notatie 37:30:55. Als u liever een aangepaste notatie wilt gebruiken, moet u de parameter voor uren tussen vierkante haken zetten, bijvoorbeeld:
[u]:mm
Terug naar begin

Een decimaal getal converteren naar een datumequivalent

Als u een seriële datum (u:mm:ss) wilt converteren naar een decimaal getal (0,00), moet u het seriële getal converteren naar een decimaal getal door naar een basis van 24 uur te converteren. Hiertoe vermenigvuldigt u als volgt de tijd met 24
=Tijd*24
waarbij Tijd het getal is dat u wilt converteren van een tijdnotatie naar een decimaal getal. Dit getal kan een celverwijzing of een reeks getallen in de functie TIJDWAARDE zijn.

Als cel A1 bijvoorbeeld een tijd van "4:30" bevat waarmee vier uur en 30 minuten wordt aangeduid, is de formule:
=A1*24
Het resultaat is 4,5.

Als de cel zowel een datum als een tijd bevat, gebruikt u de volgende formule:
=(Tijd-INTEGER(Tijd))*24
Als cel A1 bijvoorbeeld '20-6-96 4:30 AM' bevat, is de formule:
=(A1-INTEGER(A1))*24
Het resultaat is wederom 4,5.


Terug naar begin

Een decimaal getal converteren naar een datumequivalent

Als u een serieel getal (0,00) wilt converteren naar een seriële datumequivalent (u:mm:ss), moet u het seriële getal converteren naar een decimaal getal door naar een basis van 24 uur te converteren. Hiertoe deelt u de tijd als volgt door 24
=Tijd/24
waarbij Tijd het getal is dat u wilt converteren van een decimaal getal naar een serieel getal van een datum. Dit getal kan een celverwijzing of een echt getal zijn. Als cel A1 bijvoorbeeld de waarde 4,5 bevat waarmee vier uur en 30 minuten wordt aangeduid, is de formule:
=A1/24
Het resultaat is 4:30.


Terug naar begin

Bestanden overdragen tussen Microsoft Excel voor de Macintosh en Microsoft Excel voor Windows

In Excel voor de Macintosh wordt het datumsysteem 1904 gebruikt en in Excel voor Windows wordt het datumsysteem 1900 gebruikt. Dit betekent dat als u het seriële getal 1 in Excel voor de Macintosh typt en opmaakt als datum, het getal wordt weergegeven als 2-1-1904 12:00 AM. In Excel voor Windows wordt het seriële getal 1 weergegeven als 1-1-1900 12:00 AM.

Als u bestanden overdraagt van Excel voor de Macintosh naar Excel voor Windows, worden door dit verschil in de datumsystemen geen problemen veroorzaakt, omdat het datumsysteem in elk bestand is opgeslagen. Als u echter kopieert en plakt tussen bestanden met verschillende datumsystemen die afkomstig zijn van verschillende platforms, kunnen datums worden weergegeven met een verschil van vier jaar en een dag ten opzichte van de correcte datum.

Ga als volgt te werk om het datumsysteem 1904 in Excel voor Windows te gebruiken:

1. Klik op Opties in het menu Extra.
2. Open het tabblad Berekenen en schakel het selectievakje Datumsysteem 1904 in.

Ga als volgt te werk om het datumsysteem 1900 in Excel voor Macintosh te gebruiken:

1. Klik op Voorkeuren in het menu Extra.
2. Open het tabblad Berekenen en schakel het selectievakje Datumsysteem 1904 uit.

Terug naar begin