Start » KB: Sharepoint » Functies en Formules » Voorbeelden van veelgebruikte formules

Voorbeelden van veelgebruikte formules

Gepost op 31-07-2006 - KB: Sharepoint - 0 reacties

U kunt de volgende voorbeelden gebruiken in de berekende kolommen van een lijst of bibliotheek. De voorbeelden waarin niet wordt verwezen naar kolommen kunnen worden gebruikt om de standaardwaarde van een kolom aan te geven.

In dit artikel

Voorwaardelijke formules

Datum- en tijdformules

Wiskundige formules

Tekstformules

Voorwaardelijke formules

Deze formules kunnen worden gebruikt voor het volgende: de voorwaarde van een instructie testen waarbij het resultaat Ja of Nee is; een alternatieve waarde zoals OK of Niet OK testen; een lege waarde of een streepje retourneren om een Null-waarde weer te geven.

Controleren of een getal groter is dan een ander getal

Gebruik de functie ALS om deze vergelijking uit te voeren.

Kolom1	Kolom2	Formule	Beschrijving (mogelijk resultaat)
15000	9000	=[Kolom1]>[Kolom2]	Is Kolom1 groter dan Kolom2? (Ja)
15000	9000	=ALS([Kolom1]<=[Kolom2]; "OK"; "Niet OK")	Is Kolom1 kleiner dan of gelijk aan Kolom2? (Niet OK)

Een logische waarde retourneren na het vergelijken van de inhoud van kolommen

Gebruik de functies EN, OF en NIET om een logische waarde (Ja of Nee) als retourwaarde te krijgen.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (mogelijk resultaat)
15	9	8	=EN([Kolom1]>[Kolom2]; [Kolom1]<[Kolom3])	Is 15 groter dan 9 en kleiner dan 8? (Nee)
15	9	8	=OF([Kolom1]>[Kolom2]; [Kolom1]<[Kolom3])	Is 15 groter dan 9 of kleiner dan 8? (Ja)
15	9	8	=NIET([Kolom1]+[Kolom2]=24)	Is 15 plus 9 niet gelijk aan 24? (Nee)

Gebruik de functies ALS, EN en OF als u een retourwaarde wilt op basis van een andere berekening, of als u een andere retourwaarde wilt dan Ja of Nee.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (mogelijk resultaat)
15	9	8	=ALS([Kolom1]=15; "OK"; "Niet OK")	Als de waarde in Kolom1 gelijk is aan 15, is de retourwaarde "OK". (OK)
15	9	8	=ALS(EN([Kolom1]>[Kolom2]; [Kolom1]<[Kolom3]); "OK"; "Niet OK")	Als 15 groter is dan 9 en kleiner dan 8, is de retourwaarde "OK". (Niet OK)
15	9	8	=ALS(OF([Kolom1]>[Kolom2]; [Kolom1]<[Kolom3]); "OK"; "Niet OK")	Als 15 groter is dan 9 of kleiner dan 8, is de retourwaarde "OK". (OK)

Nullen weergeven als lege waarden of als streepjes

Voer een eenvoudige berekening uit als u een nul wilt weergeven. Gebruik de functie ALS om een lege waarde of een streepje als retourwaarde weer te geven.

Kolom1	Kolom2	Formule	Beschrijving (mogelijk resultaat)
10	10	=[Kolom1]-[Kolom2]	Tweede getal wordt afgetrokken van het eerste getal (0)
15	9	=ALS([Kolom1]-[Kolom2];"-";[Kolom1]-[Kolom2])	Geeft een streepje als retourwaarde wanneer het resultaat nul is (-)

Foutwaarden in kolommen verbergen

Gebruik de functie ISFOUT als u in plaats van een foutwaarde een streepje, #N/B of NB wilt weergeven.

Kolom1	Formule	Beschrijving (mogelijk resultaat)
10	=[Kolom1]/[Kolom2]	Geeft een fout als resultaat (#DEEL/0)
10	=ALS(ISFOUT([Kolom1]/[Kolom2]);"NB";[Kolom1]/[Kolom2])	Geeft NB als resultaat wanneer de waarde een fout is
10	=ALS(ISFOUT([Kolom1]/[Kolom2]);"-";[Kolom1]/[Kolom2])	Geeft een streepje als resultaat wanneer de waarde een fout is

Terug naar boven

Datum- en tijdformules

U kunt de volgende formules gebruiken om berekeningen uit te voeren op basis van datums en tijden, zoals het optellen van een aantal dagen, maanden of jaren bij een datum, of het converteren van een tijd naar een decimale waarde.

Datums optellen

Gebruik de operator voor optellen (+) om een aantal dagen bij een datum op te tellen.

Opmerking Wanneer u met datums werkt, moet u het type van de retourwaarde voor de berekende kolom instellen op Datum en tijd.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
9-6-2007	3	=[Kolom1]+[Kolom2]	Telt 3 dagen op bij 9-6-2007 (12-6-2007)
10-12-2008	54	=[Kolom1]+[Kolom2]	Telt 54 dagen op bij 10-12-2008 (2-2-2009)

Gebruik de functies DATUM, JAAR, MAAND en DAG om een aantal maanden bij een datum op te tellen.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
9-6-2007	3	=DATUM(JAAR([Kolom1]);MAAND([Kolom1])+[Kolom2];DAG([Kolom1]))	Telt 3 maanden op bij 9-6-2007 (9-9-2007)
10-12-2008	25	=DATUM(JAAR([Kolom1]);MAAND([Kolom1])+[Kolom2];DAG([Kolom1]))	Telt 25 maanden op bij 10-12-2008 (10-1-2011)

Gebruik de functies DATUM, JAAR, MAAND en DAG om een aantal jaren bij een datum op te tellen.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
9-6-2007	3	=DATUM(JAAR([Kolom1])+[Kolom2];MAAND([Kolom1]);DAG([Kolom1]))	Telt 3 jaar op bij 9-6-2007 (9-6-2010)
10-12-2008	25	=DATUM(JAAR([Kolom1])+[Kolom2];MAAND([Kolom1]);DAG([Kolom1]))	Telt 25 jaar op bij 10-12-2008 (10-12-2033)

Gebruik de functies DATUM, JAAR, MAAND en DAG om een combinatie van dagen, maanden en jaren bij een datum op te tellen.

Kolom1	Formule	Beschrijving (resultaat)
9-6-2007	=DATUM(JAAR([Kolom1])+3;MAAND([Kolom1])+1;DAG([Kolom1])+5)	Telt 3 jaar, 1 maand en 5 dagen op bij 9-6-2007 (14-7-2010)
10-12-2008	=DATUM(JAAR([Kolom1])+1;MAAND([Kolom1])+7;DAG([Kolom1])+5)	Telt 1 jaar, 7 maanden en 5 dagen op bij 10-12-2008 (15-7-2010)

Het verschil tussen twee datums berekenen

Gebruik de functie DATUMVERSCHIL om deze berekening uit te voeren.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
1-jan-1995	15-jun-1999	=DATUMVERSCHIL([Kolom1]; [Kolom2];"d")	Geeft het aantal dagen tussen de twee datums als resultaat (1626)
1-jan-1995	15-jun-1999	=DATUMVERSCHIL([Kolom1]; [Kolom2];"jm")	Geeft het aantal maanden tussen de datums als resultaat, waarbij geen rekening wordt gehouden met het jaar (5)
1-jan-1995	15-jun-1999	=DATUMVERSCHIL([Kolom1]; [Kolom2];"jd")	Geeft het aantal dagen tussen de datums als resultaat, waarbij geen rekening wordt gehouden met het jaar (165)

Het verschil tussen twee tijden berekenen

Gebruik de operator voor aftrekken (-) en de functie TEKST als u het resultaat wilt weergeven in de standaardtijdnotatie (uren:minuten:seconden). Deze methode werkt alleen als de uren geen waarde hebben groter dan 24, en de minuten en seconden geen waarde groter dan 60.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
09-06-2007 10:35	09-06-2007 15:30	=TEKST([Kolom2]-[Kolom1];"u")	De uren tussen twee tijden (4)
09-06-2007 10:35	09-06-2007 15:30	=TEKST([Kolom2]-[Kolom1];"u:mm")	De uren en minuten tussen twee tijden (4:55)
09-06-2007 10:35	09-06-2007 15:30	=TEKST([Kolom2]-[Kolom1];"u:mm:ss")	De uren, minuten en seconden tussen twee tijden (04:55:00)

Gebruik de functie INTEGER of de functies UUR, MINUUT of SECONDE als u het resultaat wilt weergeven als een totaal gebaseerd op een tijdseenheid.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
09-06-2007 10:35	10-06-2007 15:30	=INTEGER(([Kolom2]-[Kolom1])*24)	Het totaal aantal uren tussen twee tijden (28)
09-06-2007 10:35	10-06-2007 15:30	=INTEGER(([Kolom2]-[Kolom1])*1440)	Het totaal aantal minuten tussen twee tijden (1735)
09-06-2007 10:35	10-06-2007 15:30	=INTEGER(([Kolom2]-[Kolom1])*86400)	Het totaal aantal seconden tussen twee tijden (104100)
09-06-2007 10:35	10-06-2007 15:30	=UUR([Kolom2]-[Kolom1])	Het aantal uren tussen twee tijden, indien het verschil niet groter is dan 24 (4)
09-06-2007 10:35	10-06-2007 15:30	=MINUUT([Kolom2]-[Kolom1])	Het aantal minuten tussen twee tijden, indien het verschil niet groter is dan 60 (55)
09-06-2007 10:35	10-06-2007 15:30	=SECONDE([Kolom2]-[Kolom1])	Het aantal seconden tussen twee tijden, indien het verschil niet groter is dan 60 (0)

Tijden converteren

Gebruik de functie INTEGER om uren te converteren van de standaardtijdnotatie naar een decimaal getal.

Kolom1	Formule	Beschrijving (resultaat)
10:35	=([Kolom1]-INTEGER([Kolom1]))*24	Het aantal uren sinds 0:00 (10,583333)
12:15	=([Kolom1]-INTEGER([Kolom1]))*24	Het aantal uren sinds 0:00 (12,25)

Gebruik de operator voor delen en de functie TEKST om uren te converteren van een decimaal getal naar de standaardtijdnotatie (uren:minuten:seconden).

Kolom1	Formule	Beschrijving (resultaat)
23:58	=TEKST(Kolom1/24; "uu:mm:ss")	Het aantal uren, minuten en seconden sinds 0:00 (00:59:55)
2:06	=TEKST(Kolom1/24; "u:mm")	Het aantal uren en minuten sinds 0:00 (0:05)

Juliaanse datums invoegen

Een Juliaanse datum geeft een datumnotatie aan die een combinatie is van het huidige jaar en het aantal dagen sinds het begin van het jaar. 1 januari 2007 wordt bijvoorbeeld weergegeven als 2007001 en 31 december 2007 als 2007365. Deze notatie is niet gebaseerd op de Juliaanse kalender.

Gebruik de functies TEKST en DATUMWAARDE om een datum te converteren naar een Juliaanse datum.

Kolom1	Formule	Beschrijving (resultaat)
23-6-2007	=TEKST([Kolom1];"jj")&TEKST(([Kolom1]-DATUMWAARDE("1/1/"& TEKST([Kolom1];"jj"))+1);"000")	Datum in de Juliaanse datumnotatie met een jaar van twee cijfers (07174)
23-6-2007	=TEKST([Kolom1];"jjjj")&TEKST(([Kolom1]-DATUMWAARDE("1/1/"&TEKST([Kolom1];"jj"))+1);"000")	Datum in de Juliaanse datumnotatie met een jaar van vier cijfers (2007174)

Gebruik de constante 2415018,50 om een datum te converteren naar een Juliaanse datum zoals gebruikt in de astronomie. Deze formule werkt alleen voor datums na 1-3-1901 en indien u het datumsysteem 1900 gebruikt.

Kolom1	Formule	Beschrijving (resultaat)
23-6-2007	=[Kolom1]+2415018,50	Datum in de Juliaanse notatie, zoals gebruikt in de astronomie (2454274,50)

Datums tonen als dag van de week

Gebruik de functies TEKST en WEEKDAG om datums te converteren naar tekst die de dag van de week aangeeft.

Kolom1	Formule	Beschrijving (mogelijk resultaat)
19-feb-2007	=TEKST(WEEKDAG([Kolom1]); "dddd")	Hiermee wordt de dag van de week voor deze datum berekend en de volledige naam van de dag geretourneerd (maandag)
3-jan-2008	=TEKST(WEEKDAG([Kolom1]); "ddd")	Hiermee wordt de dag van de week voor deze datum berekend en de afgekorte naam van de dag geretourneerd (don)

Terug naar boven

Wiskundige formules

U kunt de volgende formules gebruiken voor een groot aantal wiskundige berekeningen, zoals: optellen, aftrekken, vermenigvuldigen en delen van getallen; berekenen van het gemiddelde of de mediaan van getallen; afronden van een getal; tellen van waarden.

Getallen optellen

Gebruik de operator voor optellen (+) of de functie SOM om getallen in twee of meer kolommen in een rij op te tellen.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
6	5	4	=[Kolom1]+[Kolom2]+[Kolom3]	Hiermee worden de waarden in de eerste drie kolommen opgeteld (15)
6	5	4	=SOM([Kolom1];[Kolom2];[Kolom3])	Hiermee worden de waarden in de eerste drie kolommen opgeteld (15)
6	5	4	=SOM(ALS([Kolom1]>[Kolom2]; [Kolom1]-[Kolom2]; 10); [Kolom3])	Als Kolom1 groter is dan Kolom2, wordt het verschil opgeteld bij Kolom3. Zo niet, wordt 10 opgeteld bij Kolom3 (5)

Getallen aftrekken

Gebruik de operator voor aftrekken (-) of de functie SOM met negatieve getallen om getallen in twee of meer kolommen in een rij af te trekken.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
15000	9000	-8000	=[Kolom1]-[Kolom2]	Hiermee wordt 9000 afgetrokken van 15000 (6000)
15000	9000	-8000	=SOM([Kolom1];[Kolom2];[Kolom3])	Hiermee worden de getallen in de eerste drie kolommen opgeteld, inclusief negatieve waarden (16000)

Het verschil tussen twee getallen berekenen als percentage

Gebruik de functie ABS en de operatoren voor aftrekken (-) en delen (/).

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
2342	2500	=([Kolom2]-[Kolom1])/ABS([Kolom1])	Percentagewijziging (6,75% of 0,06746)

Getallen vermenigvuldigen

Gebruik de operator voor vermenigvuldigen (*) of de functie PRODUCT om getallen in twee of meer kolommen in een rij te vermenigvuldigen.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
5	2	=[Kolom1]*[Kolom2]	Hiermee worden de getallen in de eerste twee kolommen vermenigvuldigd (10)
5	2	=PRODUCT([Kolom1];[Kolom2])	Hiermee worden de getallen in de eerste twee kolommen vermenigvuldigd (10)
5	2	=PRODUCT([Kolom1];[Kolom2];2)	Hiermee worden de getallen in de eerste twee kolommen en het getal 2 vermenigvuldigd (20)

Getallen delen

Gebruik de operator voor delen (/) om de getallen in twee of meer kolommen in een rij te delen.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
15000	12	=[Kolom1]/[Kolom2]	Hiermee wordt 15000 gedeeld door 12 (1250)
15000	12	=([Kolom1]+10000)/[Kolom2]	Hiermee worden 15000 en 10000 opgeteld en wordt het totaal gedeeld door 12 (2083)

Het gemiddelde van getallen berekenen

Gebruik de functie GEMIDDELDE om het gemiddelde van getallen in twee of meer kolommen in een rij te berekenen.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
6	5	4	=GEMIDDELDE([Kolom1]; [Kolom2];[Kolom3])	Het gemiddelde van de getallen in de eerste drie kolommen (5)
6	5	4	=GEMIDDELDE(ALS([Kolom1]>[Kolom2]; [Kolom1]-[Kolom2]; 10); [Kolom3])	Als Kolom1 groter is dan Kolom2, wordt het gemiddelde berekend van het verschil en Kolom3. Zo niet, wordt het gemiddelde berekend van de waarde 10 en Kolom3 (2,5)

De mediaan van getallen berekenen

De mediaan is de centrale waarde van een geordende reeks getallen. Gebruik de functie MEDIAAN om de mediaan van een groep getallen te berekenen.

A	B	C	D	E	F	Formule	Beschrijving (resultaat)
10	7	9	27	0	4	=MEDIAAN(A; B; C; D; E; F)	Is de mediaan van de getallen in de eerste 6 kolommen (8)

Het kleinste of grootste getal in een reeks berekenen

Gebruik de functies MIN en MAX om het kleinste of grootste getal te berekenen in twee of meer kolommen in een rij.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
10	7	9	=MIN([Kolom1]; [Kolom2]; [Kolom3])	Kleinste getal (7)
10	7	9	=MAX([Kolom1]; [Kolom2]; [Kolom3])	Grootste getal (10)

Waarden tellen

Gebruik de functie AANTAL om numerieke waarden te tellen.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
Appel		12-12-2007	=AANTAL([Kolom1]; [Kolom2]; [Kolom3])	Hiermee wordt geteld hoeveel kolommen numerieke waarden bevatten. Datum en tijd, tekst en Null-waarden worden niet meegeteld (0)
Ã¢â€šÂ¬12	#DEEL/0!	1,01	=AANTAL([Kolom1]; [Kolom2]; [Kolom3])	Hiermee wordt geteld hoeveel kolommen numerieke waarden bevatten. Fouten en logische waarden worden niet meeberekend (2)

Een getal verhogen of verlagen met een percentage

Gebruik de operator voor het percentage (%) om deze berekening uit te voeren.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
23	3%	=[Kolom1]*(1+5%)	Hiermee wordt het getal in Kolom1 verhoogd met 5% (24,15)
23	3%	=[Kolom1]*(1+[Kolom2])	Hiermee wordt het getal in Kolom1 verhoogd met het percentage in Kolom2: 3% (23,69)
23	3%	=[Kolom1]*(1-[Kolom2])	Hiermee wordt het getal in Kolom1 verlaagd met het percentage in Kolom2: 3% (22,31)

Een getal tot een macht verheffen

Gebruik de operator voor het exponentteken (^) of de functie MACHT om deze berekening uit te voeren.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
5	2	=[Kolom1]^[Kolom2]	Hiermee wordt het kwadraat van vijf berekend (25)
5	3	=MACHT([Kolom1]; [Kolom2])	Hiermee wordt de derde macht van vijf berekend (125)

Een getal afronden

Gebruik de functie AFRONDEN.NAAR.BOVEN, ONEVEN of EVEN om een getal naar boven af te ronden.

Kolom1	Formule	Beschrijving (resultaat)
20,3	=AFRONDEN.NAAR.BOVEN([Kolom1];0)	Hiermee wordt 20,3 naar boven afgerond op het dichtstbijzijnde gehele getal (21)
-5,9	=AFRONDEN.NAAR.BOVEN([Kolom1];0)	Hiermee wordt -5,9 naar boven afgerond op het dichtstbijzijnde gehele getal (-5)
12,5493	=AFRONDEN.NAAR.BOVEN([Kolom1];2)	Hiermee wordt 12,5493 naar boven afgerond op het dichtstbijzijnde honderdste deel (twee decimale plaatsen) (12,55)
20,3	=EVEN([Kolom1])	Hiermee wordt 20,3 naar boven afgerond op het dichtstbijzijnde even getal (22)
20,3	=ONEVEN([Kolom1])	Hiermee wordt 20,3 naar boven afgerond op het dichtstbijzijnde oneven getal (21)

Gebruik de functie AFRONDEN.NAAR.BENEDEN om een getal naar beneden af te ronden.

Kolom1	Formule	Beschrijving (resultaat)
20,3	=AFRONDEN.NAAR.BENEDEN([Kolom1];0)	Hiermee wordt 20,3 naar beneden afgerond op het dichtstbijzijnde gehele getal (20)
-5,9	=AFRONDEN.NAAR.BENEDEN([Kolom1];0)	Hiermee wordt -5,9 naar beneden afgerond op het dichtstbijzijnde gehele getal (-6)
12,5493	=AFRONDEN.NAAR.BENEDEN([Kolom1];2)	Hiermee wordt 12,5493 naar beneden afgerond op het dichtstbijzijnde honderdste deel (twee decimale plaatsen) (12,54)

Gebruik de functie AFRONDEN om een getal af te ronden naar het dichtstbijzijnde getal of breukdeel.

Kolom1	Formule	Beschrijving (resultaat)
20,3	=AFRONDEN([Kolom1];0)	Hiermee wordt 20,3 naar beneden afgerond, omdat het breukdeel kleiner is dan 0,5 (20)
5,9	=AFRONDEN([Kolom1];0)	Hiermee wordt 5,9 naar boven afgerond, omdat het breukdeel groter is dan 0,5 (6)
-5,9	=AFRONDEN([Kolom1];0)	Hiermee wordt -5,9 naar beneden afgerond, omdat het breukdeel kleiner is dan -0,5 (-6)
1,25	=AFRONDEN([Kolom1];1)	Hiermee wordt het getal afgerond op het dichtstbijzijnde tiende deel (één decimale plaats). Het deel dat wordt afgerond is gelijk aan of groter dan 0,05 en dus wordt het getal naar boven afgerond (resultaat: 1,3)
30,452	=AFRONDEN([Kolom1];2)	Hiermee wordt het getal afgerond op het dichtstbijzijnde honderdste deel (twee decimale plaatsen). Het deel dat wordt afgerond (0,002) is kleiner dan 0,005 en dus wordt het getal naar beneden afgerond (resultaat: 30,45)

Gebruik de functies AFRONDEN, AFRONDEN.NAAR.BOVEN, AFRONDEN.NAAR.BENEDEN, INTEGER of LENGTE om een getal af te ronden op het significante cijfer groter dan 0.

Kolom1	Formule	Beschrijving (resultaat)
5492820	=AFRONDEN([Kolom1];3-LENGTE(INTEGER([Kolom1])))	Hiermee wordt het getal afgerond op 3 significante cijfers (5490000)
22230	=AFRONDEN.NAAR.BENEDEN([Kolom1];3-LENGTE(INTEGER([Kolom1])))	Hiermee wordt het onderste getal naar beneden afgerond op 3 significante cijfers (22200)
5492820	=AFRONDEN.NAAR.BOVEN([Kolom1]; 5-LENGTE(INTEGER([Kolom1])))	Hiermee wordt het bovenste getal naar boven afgerond op 5 significante cijfers (5492900)

Terug naar boven

Tekstformules

U kunt de volgende formules gebruiken om met tekst te werken, zoals combineren of samenvoegen van waarden uit meerdere kolommen, vergelijken van de inhoud van kolommen, verwijderen van tekens en spaties en herhalen van tekens.

Wisselen tussen hoofdletters en kleine letters

Gebruik de functie HOOFDLETTERS, KLEINE.LETTERS of BEGINLETTERS om in een tekst te wisselen tussen hoofdletters en kleine letters.

Kolom1	Formule	Beschrijving (resultaat)
ties Arts	=HOOFDLETTERS([Kolom1])	Wijzigt de tekst in hoofdletters (TIES ARTS)
ties Arts	=KLEINE.LETTERS([Kolom1])	Wijzigt de tekst in kleine letters (ties arts)
ties Arts	=BEGINLETTERS([Kolom1])	Wijzigt de tekst in alles beginhoofdletter (Ties Arts)

Voor- en achternaam combineren

Gebruik de operator En-teken (&) of de functie TEKST.SAMENVOEGEN om voor- en achternaam te combineren.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
Jeroen	Cool	=[Kolom1]&[Kolom2]	Hiermee worden de twee tekenreeksen gecombineerd (JeroenCool)
Jeroen	Cool	=[Kolom1]&" "&[Kolom2]	Hiermee worden de twee tekenreeksen gecombineerd en gescheiden door een spatie (Jeroen Cool)
Jeroen	Cool	=[Kolom2]&", "&[Kolom1]	Hiermee worden de twee tekenreeksen gecombineerd en gescheiden door een komma en een spatie (Cool, Jeroen)
Jeroen	Cool	=TEKST.SAMENVOEGEN([Kolom2]; ","; [Kolom1])	Hiermee worden de twee tekenreeksen gecombineerd en gescheiden door een komma (Cool,Jeroen)

Tekst en getallen uit verschillende kolommen combineren

Gebruik de functie TEKST.SAMENVOEGEN, de operator En-teken (&), of de functie TEKST in combinatie met de operator En-teken om tekst en getallen te combineren.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
Pascaline	28	=[Kolom1]&" verkocht "&[Kolom2]&" eenheden."	Hiermee wordt de inhoud van de formule gecombineerd in een zin (Pascaline verkocht 28 eenheden.)
Overeem	40%	=[Kolom1]&" verkocht "&TEKST([Kolom2];"0%")&" van de totale verkopen."	Hiermee wordt de inhoud van de formule gecombineerd in een zin (Overeem verkocht 40% van de totale verkopen.) Opmerking Met de functie TEKST wordt de opgemaakte waarde van Kolom2 toegevoegd en niet de onderliggende waarde, die 0,4 bedraagt.
Pascaline	28	=TEKST.SAMENVOEGEN([Kolom1];" verkocht ";[Kolom2];" eenheden.")	Hiermee wordt de inhoud van de formule gecombineerd in een zin (Pascaline verkocht 28 eenheden.)

Tekst combineren met een datum of tijd

Gebruik de functie TEKST en de operator En-teken (&) om tekst te combineren met een datum of tijd.

Kolom1	Kolom2	Formule	Beschrijving (resultaat)
Factuurdatum	5-jun-2007	="Afschriftdatum: "&TEKST([Kolom2]; "d-mmm-jjjj")	Hiermee wordt tekst gecombineerd met een datum (Afschriftdatum: 5-jun-2007)
Factuurdatum	5-jun-2007	=[Kolom1]&" "&TEKST([Kolom2]; "mmm-dd-jjjj")	Hiermee worden een tekst en een datum uit verschillende kolommen gecombineerd in één kolom (Factuurdatum 5-jun-2007)

Inhoud van kolommen vergelijken

Gebruik de functies GELIJK en OF om een kolom te vergelijken met een andere kolom of een lijst met waarden.

Kolom1	Kolom2	Formule	Beschrijving (mogelijk resultaat)
BD122	BD123	=GELIJK([Kolom1];[Kolom2])	Hiermee worden de eerste twee kolommen vergeleken (Nee)
BD122	BD123	=GELIJK([Kolom1]; "BD122")	Hiermee wordt de inhoud van Kolom1 vergeleken met de tekenreeks 'BD122' (Ja)

Controleren of een kolomwaarde of een deel daarvan overeenkomt met specifieke tekst

Gebruik de functies ALS, ZOEK, VIND.SPEC en ISGETAL om te controleren of een kolomwaarde of een deel daarvan overeenkomt met specifieke tekst.

Kolom1	Formule	Beschrijving (mogelijk resultaat)
Arts	=ALS([Kolom1]="Arts"; "OK"; "Niet OK")	Hiermee wordt gecontroleerd of Kolom1 de waarde Arts heeft (OK)
Arts	=ALS(ISGETAL(ZOEK("a";[Kolom1])); "OK"; "Niet OK")	Hiermee wordt gecontroleerd of Kolom1 de letter a bevat (OK)
BD123	=ISGETAL(ZOEK("BD";[Kolom1]))	Hiermee wordt gecontroleerd of Kolom1 BD bevat (Ja)

Niet-lege kolommen tellen

Gebruik de functie AANTALARG om niet-lege kolommen te tellen.

Kolom1	Kolom2	Kolom3	Formule	Beschrijving (resultaat)
Verkopen	19		=AANTALARG([Kolom1]; [Kolom2])	Hiermee wordt het aantal niet-lege kolommen geteld (2)
Verkopen	19		=AANTALARG([Kolom1]; [Kolom2]; [Kolom3])	Hiermee wordt het aantal niet-lege kolommen geteld (2)

Tekens uit tekst verwijderen

Gebruik de functies LENGTE, LINKS en RECHTS om tekens uit tekst te verwijderen.

Kolom1	Formule	Beschrijving (resultaat)
Vitamine A	=LINKS([Kolom1];LENGTE([Kolom1])-2)	Geeft als retourwaarde 7 tekens (9-2), gerekend vanaf links (Vitamine)
Vitamine B1	=RECHTS([Kolom1]; LENGTE([Kolom1])-8)	Geeft als retourwaarde 2 tekens (10-8), gerekend vanaf rechts (B1)

Spaties verwijderen aan het begin en einde van een kolom

Gebruik de functie SPATIES.WISSEN om spaties uit een kolom te verwijderen.